Arduino Trimmrad 2 zur Einstellung der Flugzeug-Trimmung

/*
 * Arduino HID Trim Wheel 2
 *
 * Author	Jan Wischniowski <jan.wischniowski@metanox.de>
 * URL		https://www.metanox.de/
 * Version	1.0.0
 * License	GNU GENERAL PUBLIC LICENSE Version 3
*/
 
/*
 * Strg + Shift + P -> Advanced Options in Arduino IDE 2.0!
*/
 
#include "Arduino.h"
#include "HID-Project.h"
 
const int ledBlue					= 2;
const int ledGreen					= 3;
const int ledRed					= 4;
const int rotaryClock				= 5;	// Pin 5 to CLK (clock) on rotary encoder.
const int rotaryData				= 6;	// Pin 6 to DT (data) on rotary encoder.
const int rotarySwitch				= 7;	// Pin 7 to SW (switch) on rotary encoder.
 
int rotaryXAxis;							// Result between [-32768 .. +32767].
float rotaryXAxisNormalized;				// Result between [-100.0 .. +100.0] (percent).
 
 
int rotaryCounter					= 0;
int rotaryClockCurrentState;
int rotaryClockLastState;
int rotaryButton;
unsigned long rotaryButtonLastPress = 0;
int rotaryButtonCurrentState		= 0;
String rotaryCurrentDirection		= "";
 
void setup()
{
	// Set encoder pins as inputs.
	pinMode(rotaryClock, INPUT);
	pinMode(rotaryData, INPUT);
	pinMode(rotarySwitch, INPUT_PULLUP);
 
	pinMode(ledRed, OUTPUT);
	pinMode(ledGreen, OUTPUT);
	pinMode(ledBlue, OUTPUT);
 
	// Read the initial state of CLK.
	rotaryClockLastState = digitalRead(rotaryClock);
 
	// Reset.
	digitalWrite(ledRed, LOW);
	digitalWrite(ledGreen, LOW);
	digitalWrite(ledBlue, LOW);
 
	Gamepad.begin();
 
	// Setup Serial Monitor.
	Serial.begin(9600);
}
 
void loop()
{
	// Read the button state.
	rotaryButton = digitalRead(rotarySwitch);
 
	//If we detect LOW signal, button is pressed.
	if (rotaryButton == LOW)
	{
		// If 50ms have passed since last LOW pulse, it means that the button has been pressed, released and pressed again.
		if (millis() - rotaryButtonLastPress > 50)
		{
			rotaryCounter				= 0;
			rotaryXAxis					= 0;
			rotaryXAxisNormalized		= 0;
 
			rotaryButtonCurrentState	= 1;
 
			Serial.println("Button pressed!");
 
			Gamepad.press(1);
 
			Gamepad.rxAxis(rotaryXAxis);
 
			digitalWrite(ledRed, LOW);
			digitalWrite(ledGreen, LOW);
			digitalWrite(ledBlue, HIGH);
 
			Serial.print("Direction: ");
			Serial.print(rotaryCurrentDirection);
			Serial.print(" | ");
			Serial.print("rotaryCounter: ");
			Serial.print(rotaryCounter);
			Serial.print(" | ");
			Serial.print("rotaryXAxis: ");
			Serial.print(rotaryXAxis);
			Serial.print(" | ");
			Serial.print("rotaryXAxisNormalized: ");
			Serial.println(rotaryXAxisNormalized);
		}
 
		// Remember last button press event.
		rotaryButtonLastPress = millis();
	}
	else
	{
		if (rotaryButtonCurrentState == 1)
		{
			rotaryButtonCurrentState = 0;
 
			digitalWrite(ledRed, LOW);
			digitalWrite(ledGreen, LOW);
			digitalWrite(ledBlue, LOW);
 
			Serial.println("Button released!");
			Gamepad.release(1);
		}
	}
 
	// Read the current state of CLK.
	rotaryClockCurrentState = digitalRead(rotaryClock);
 
	// If last and current state of CLK are different, then pulse occurred.
	// React to only 1 state change to avoid double count.
	if (rotaryClockCurrentState != rotaryClockLastState && rotaryClockCurrentState == 1)
	{
		// If the rotaryData state is different than the CLK state then the encoder is rotating CCW so decrement.
		if (digitalRead(rotaryData) != rotaryClockCurrentState)
		{
			rotaryCounter --;
			rotaryCurrentDirection = "CW";
		} else {
			// Encoder is rotating CW so increment.
			rotaryCounter ++;
			rotaryCurrentDirection = "CCW";
		}
 
		if (200<=rotaryCounter)
		{
			rotaryCounter = 200;
		}
		if (-200>=rotaryCounter)
		{
			rotaryCounter = -200;
		}
 
		rotaryXAxis = (int)((float)rotaryCounter * 163.835); // Welche Schrittweite ist nötig, um 0,5-Prozent-Schritte mit jedem Dreh-Intervall zu erlangen? -> 32767/200 = 163,835.
 
		if (32767<=rotaryXAxis)
		{
			rotaryXAxis = 32767;
		}
		if (-32768>=rotaryXAxis)
		{
			rotaryXAxis = -32768;
		}
 
		rotaryXAxisNormalized = (((float)rotaryXAxis/32768) * 100.0);
 
		Serial.print("Direction: ");
		Serial.print(rotaryCurrentDirection);
		Serial.print(" | ");
		Serial.print("rotaryCounter: ");
		Serial.print(rotaryCounter);
		Serial.print(" | ");
		Serial.print("rotaryXAxis: ");
		Serial.print(rotaryXAxis);
		Serial.print(" | ");
		Serial.print("rotaryXAxisNormalized: ");
		Serial.println(rotaryXAxisNormalized);
 
		Gamepad.rxAxis(rotaryXAxis);
 
		if (rotaryCounter<0)
		{
			digitalWrite(ledRed, HIGH);
			digitalWrite(ledGreen, LOW);
			digitalWrite(ledBlue, LOW);
		}
		else if (rotaryCounter>0)
		{
			digitalWrite(ledRed, LOW);
			digitalWrite(ledGreen, HIGH);
			digitalWrite(ledBlue, LOW);
		}
		else
		{
			digitalWrite(ledRed, LOW);
			digitalWrite(ledGreen, LOW);
			digitalWrite(ledBlue, LOW);
		}
	}
 
	// Remember last CLK state.
	rotaryClockLastState = rotaryClockCurrentState;
 
	Gamepad.write();
 
	// Put in a slight delay to help debounce the reading.
	delay(1);
}